QT       += core gui widgets network

greaterThan(QT_MAJOR_VERSION, 5): QT += core5compat

CONFIG += c++17

TARGET = CalibratorLauncher
TEMPLATE = app

# 编译输出目录设置 - 保持根目录整洁
DESTDIR = $$PWD/build
OBJECTS_DIR = $$PWD/build/obj
MOC_DIR = $$PWD/build/moc
RCC_DIR = $$PWD/build/rcc
UI_DIR = $$PWD/build/ui

# 应用程序信息
VERSION = 1.0.0
QMAKE_TARGET_COMPANY = "智能校验仪"
QMAKE_TARGET_PRODUCT = "CalibratorLauncher"
QMAKE_TARGET_DESCRIPTION = "智能校验仪启动器"
QMAKE_TARGET_COPYRIGHT = "Copyright 2025"

# 源文件
SOURCES += \
    main.cpp \
    mainwindow.cpp \
    widgets/launcherpage.cpp \
    widgets/appicon.cpp \
    widgets/statusbar.cpp \
    widgets/devicestatuswidget.cpp \
    widgets/dockbar.cpp \
    widgets/pageindicator.cpp \
    widgets/procedurelistwidget.cpp \
    widgets/procedureplayerwidget.cpp \
    widgets/signalmeasurementwidget.cpp \
    widgets/channelstatuswidget.cpp \
    widgets/tablewidgetfactory.cpp \
    widgets/tableoverlaywidget.cpp \
    widgets/overlaydialogswidget.cpp \
    widgets/settingswidget.cpp \
    widgets/datamanagementwidget.cpp \
    widgets/wirelesswidget.cpp \
    widgets/networktestwidget.cpp \
    widgets/waveformwidget.cpp \
    widgets/dualchannelwidget.cpp \
    widgets/signaltrimwidget.cpp \
    hardware/channelmanager.cpp \
    procedure/proceduremanager.cpp \
    procedure/procedureengine.cpp \
    procedure/procedureparser.cpp \
    procedure/functionregistry.cpp \
    utils/configmanager.cpp \
    utils/stylehelper.cpp

HEADERS += \
    mainwindow.h \
    widgets/launcherpage.h \
    widgets/appicon.h \
    widgets/statusbar.h \
    widgets/devicestatuswidget.h \
    widgets/dockbar.h \
    widgets/pageindicator.h \
    widgets/procedurelistwidget.h \
    widgets/procedureplayerwidget.h \
    widgets/signalmeasurementwidget.h \
    widgets/channelstatuswidget.h \
    widgets/tablewidgetfactory.h \
    widgets/tableoverlaywidget.h \
    widgets/overlaydialogswidget.h \
    widgets/settingswidget.h \
    widgets/datamanagementwidget.h \
    widgets/wirelesswidget.h \
    widgets/networktestwidget.h \
    widgets/waveformwidget.h \
    widgets/dualchannelwidget.h \
    widgets/signaltrimwidget.h \
    hardware/channelmanager.h \
    procedure/proceduredata.h \
    procedure/proceduremanager.h \
    procedure/procedureengine.h \
    procedure/procedureparser.h \
    procedure/functionregistry.h \
    utils/configmanager.h \
    utils/stylehelper.h

RESOURCES += \
    resources.qrc

# ryml 库支持 (用于解析 YAML/JSON)
INCLUDEPATH += /opt/homebrew/Cellar/rapidyaml/0.10.0/include
LIBS += -L/opt/homebrew/Cellar/rapidyaml/0.10.0/lib -lryml -lc4core

# 默认部署规则
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

# Windows 图标
# win32:RC_ICONS += icons/app.ico

# macOS 图标 (需要 .icns 文件)
# macx:ICON = icons/app.icns